Larian Studios Forums Divinity - Original Sin Divinity Original Sin - Mods [MOD] Under Siege (beta 1.1.3)

Version 1
SubGoalCombiner SGC_AND
INITSECTION
// --------------------------------------------------------------------------------------------------
// A Script to make items in a trigger owned by NPC and display region name when player enters in it
// --------------------------------------------------------------------------------------------------

// Exclude usable items from private belongings
// This must be defined before HUS_MyProperty(...)
// ---------------------------------------------------------------------------------
DB_HUS_MP_Ex("LTS_Rich_Candleholder_D_14c222be-a500-4162-827f-c49494b39233");
DB_HUS_MP_Ex("LTS_Rich_Candleholder_B_727742e8-dd09-46e6-9a4f-f5b1229bb783");
DB_HUS_MP_Ex("LTS_Rich_Candleholder_A_fc0d87e4-e9f9-4956-88cc-28cf6de5d7af");
DB_HUS_MP_Ex("05m_Citizen_A_Door_A_Item_1334583f-347d-4ac7-8ee5-efbfba5fd999");
DB_HUS_MP_Ex("05m_HouseFarm_A_Hatch_A_Item_f6ad6f51-bf90-4ec4-a42b-6980766646f2");


// Initialize NPC Owned Items and Sub Regions
// HUS_MyProperty(TRIGGER, NPC, SubRegionName);
// ---------------------------------------------------------------------------------
HUS_MyProperty(TRIGGER_HUS_MP_Tavern, CHARACTER_UnderSiege_Bernard, "HUS_SR_Tavern");
HUS_MyProperty(TRIGGER_HUS_MP_Hunter, CHARACTER_UnderSiege_Hilbert, "HUS_SR_Hunter");
HUS_MyProperty(TRIGGER_HUS_MP_Magic, CHARACTER_UnderSiege_Maribel, "HUS_SR_Magic");
HUS_MyProperty(TRIGGER_HUS_MP_Lisbeth, CHARACTER_UnderSiege_Lisbeth, "");
HUS_MyProperty(TRIGGER_HUS_MP_Katherine, CHARACTER_UnderSiege_Katherine, "");
HUS_MyProperty(TRIGGER_HUS_MP_Captain, CHARACTER_UnderSiege_Captain, "");
HUS_MyProperty(TRIGGER_HUS_MP_Gilbert, CHARACTER_NULL, "HUS_SR_Gilbert");
HUS_MyProperty(TRIGGER_HUS_MP_DigSite, CHARACTER_NULL, "HUS_SR_Maribel");
HUS_MyProperty(TRIGGER_HUS_MP_Tower, CHARACTER_NULL, "HUS_SR_Tower");
HUS_MyProperty(TRIGGER_HUS_MP_Crypt, CHARACTER_NULL, "HUS_SR_Crypt");



KBSECTION

PROC HUS_ClearProperty((TRIGGER)_Trig)
AND DB_HUS_MP_Ex(_List)
THEN
TriggerClearItemTemplateOwners(_Trig, _List);


// If a non-null NPC character is specified. Mark all items to belong to it 
// Then clear some usable items from private belongings
// ---------------------------------------------------------------------------------
PROC HUS_MyProperty((TRIGGER)_Trig, (CHARACTER)_Char, (STRING)_Area)
AND _Char != CHARACTER_NULL
THEN
TriggerSetItemOwner(_Trig, _Char);
HUS_ClearProperty(_Trig);


// If the Area name is specified then record it in database
// ---------------------------------------------------------------------------------
PROC HUS_MyProperty((TRIGGER)_Trig, (CHARACTER)_Char, (STRING)_Area)
AND _Area != ""
AND NOT DB_HUS_Area(_Trig, _)
THEN
DB_HUS_Area(_Trig, _Area);
TriggerRegisterForPlayers(_Trig);


// Display SubRegion Name when player enters in it
// ---------------------------------------------------------------------------------
IF CharacterEnteredTrigger(_Char, _Trig)
AND _Char.isPlayer()
AND DB_HUS_Area(_Trig, _Name)
THEN CharacterEnteredSubRegion(_Char, _Name);

EXITSECTION

ENDEXITSECTION
ParentTargetEdge "__Start"