Larian Studios Forums Divinity - Original Sin Divinity - Original Sin - Technical Issues [Bug] Cat aggro

////////////////////////////////////////////////////////////////////////////////////////////////////
// An evil dude is an npc whose alignment relations define him to be agressive towards a good guy -
// let's take Lanilor as the definition of a good guy.
// Note: this does not mean that the evil dude will be agressive towards the player - au contraire!
// The evil dude will be smart enough to feign friendlyness to the player in an attempt to mislead him.
// This is done automatically at game start by calling SetFriendlyAlignmentWithHero(_Npc);
PROC
SetEvilDudeStatus((CHARACTER)_Npc)
AND
NOT EvilDude(_Npc)
AND
//TODO: really?
CharacterGetRelationToCharacter(_Npc,CHARACTER_CYS_Arhu,_Alignment)
THEN
SetEvilDudeStatus_1(_Npc,_Alignment);

PROC
SetEvilDudeStatus_1((CHARACTER)_Npc,(INTEGER)_Alignment)
AND
_Alignment < 25
THEN
EvilDude(_Npc);

////////////////////////////////////////////////////////////////////////////////////////////////////
// Amoral npcs don't mind if they're addressed by the hero when he has weapons drawn
// Amoral npcs don't mind/comment about stealing.
//
// MoralNpc/1 overrides as you can see in the following rules:
//
IF
EvilDude(_Npc)
AND
NOT MoralNpc(_Npc)
THEN
Amoral(_Npc);

IF
Unintelligent(_Npc)
AND
NOT MoralNpc(_Npc)
THEN
Amoral(_Npc);

////////////////////////////////////////////////////////////////////////////////////////////////////
// Evil dudes do not trade
IF
EvilDude(_Npc)
THEN
ProcDisablePlayerTrade(_Npc);

PROC
ProcDisablePlayerTrade((CHARACTER)_Npc)
AND
_Player.isPlayer()
THEN
CannotTrade(_Player,_Npc);

PROC
ProcDisablePlayerTrade((CHARACTER)_Npc)
AND
DB_DefinedCompanions(_Player)
THEN
CannotTrade(_Player,_Npc);