As Tinkerer said, my example was just that - an example on how the character iterator works. You can see it actually worked correctly, given the log messages you shared:
Originally Posted by Detect
Design: Osiris triggered an assert: [Detect] Iterator ran on Master Of Time


As for when to set your characters off-stage, one idea would be to do so when the player steps into a trigger you designate as the "level transition start" trigger. This task would also be easier if you added all your monsters to a shared database, instead of each type getting its own. If you need to later retrieve certain types of monsters, you could just add a shared value in the DB like so:
Code
TemporaryCharacterCreateAtPosition(_X, _Y, _Z, "CHARACTERGUID_Monkworks_Boar000_7c0d5742-cda0-4381-b41f-9dccfba783cb", 1, _Boar000)
THEN
DB_MonkWorks_SpawnedEnemies("Boar", _Boar000);

I suggest leaving their database entries in-tact when they die, and removing them when you actually set them off-stage:

INIT:
Code
//Replace this with your actual trigger
DB_MonkWorks_LevelTransitionTrigger((TRIGGERGUID)LevelTransition_Level1_bdc5b3da-041a-4d98-bb68-149869203e83);

KB:
Code
IF
CharacterEnteredTrigger(_Character, _Trigger)
AND
DB_IsPlayer(_Character)
AND
DB_MonkWorks_LevelTransitionTrigger(_Trigger)
AND
NOT DB_MonkWorks_CleanupRunning(_)
AND
MonkWorks_QRY_CleanupNeeded()
THEN
DB_MonkWorks_CleanupRunning(1);
MonkWorks_System_Cleanup();

QRY
MonkWorks_QRY_CleanupNeeded()
AND
SysCount("DB_MonkWorks_SpawnedEnemies", 2, _TotalEnemies)
AND
_TotalEnemies > 0
THEN
DB_NOOP(1);

PROC
MonkWorks_System_Cleanup()
AND
DB_MonkWorks_SpawnedEnemies(_Type, _Enemy)
THEN
SetOnStage(_Enemy, 0);
NOT DB_MonkWorks_SpawnedEnemies(_Type, _Enemy);

PROC
MonkWorks_System_Cleanup()
AND
NOT DB_MonkWorks_SpawnedEnemies(_,_)
THEN
NOT DB_MonkWorks_CleanupRunning(1);


As you can see here, I made both a custom query to check if we need to clean up (if any spawned enemies are in the database), and a proc for actually iterating through said database and setting the enemy off stage.

This is pretty basic stuff (once you're familar with the story scripting syntax/basics!), so I recommend giving this a read, and the articles listed under "Recommended Reading" as well.

LaughingLeader's DOS2 Mods